:: =============================================
:: AutoHelp for: Acronis TrueImage 9
:: =============================================
::                      INIT
@echo off&CD %~dp0&call SCRIPTS\SCRIPT_MNGR.cmd

::         The "normal" initial calls:
%VarsSystemEtc% & %VarsLocalStrings% & %CreateHelp%
               %Intro% & %AutoLang%
 %CreateStartInf% & %PrintINFhead% & %CreateReset%

::       NOTE: Set the plugin details in
::           SCRIPTS\PlugSettings.ini
:: =============================================


:: Main Family version selection:
%COMBO% "2" "Select the Version ..." "Vers_Sel_Data.dat" "Vers_Sel_txt.dat" ""
set Vers_Family=%result%
if "%Vers_Family%" == "I am not sure what my version is" %AbortConfig% "Please find out what the version is."
if "%BTN%" == "cancel" %AbortConfig% ""

call :Adapt_To_Version
if not "%TI_Main_vers%" == "9" %AbortConfig% "This plugin is only for TrueImage version 9."

%GetProgPath% "HKEY_LOCAL_MACHINE\SOFTWARE\%ProgPath_REG_KEY%" "MainExePath"

call :Veryfy_ProgPath

set Exclude=BartPE,
%GetFolder%

set Exclude=Acronis Disk Director,DiskDirector,
%GetFolder% "%CommonProgramFiles%\Acronis" "AcronisCommonFiles"

call :Get_SYS_Files

%Add2Inf% "Credits.dat"

%IniSetStrings%
%IniSetStrings% "Prog_On_CD" "%Prog_On_CD%"

%CreateNu2XML%

%WinNtDir_a%

call :ProfileFix_Check

if "%XPE%" == "1" %XPEshortcuts%

call :DCOM_LAUNCH_FIX

set text=LIC Main Program
%Reg2Inf% -h1 "HKEY_LOCAL_MACHINE\SOFTWARE\Acronis\TrueImage" "%LIC_REG_VALUE%"	

%line%
%line%

set text=LIC and other required settings for UniversalRestore
if "%U_Restore%" == "1" (
	%Reg2Inf% -h1 "HKEY_LOCAL_MACHINE\SOFTWARE\Acronis\UniversalRestore" "%LIC_REG_VALUE%"	
	echo [SourceDisksFiles] %OUT%
	echo SCRIPTS\Include\ura.exe=2,,1 %OUT%
	echo [Default.AddReg] %OUT%
	echo 0x2, "Environment", "TEMP", "%%ramdrv%%" %OUT%
	echo 0x2, "Environment", "TMP", "%%ramdrv%%" %OUT%

	%TextBox% "1" "UniversalRestore ..." "UniversalRestore_Txt.dat"
)

%Add2Inf% "StaticINF_%Lead_Version%.dat"
:: %Add2Inf% "1x1Support_On_CD.dat"
%line%
%line%

set text=REGIONAL SETTINGS
%REG2INF% -h1 -S "HKCU\Control Panel\International"

call :UPPER_FILTERS

:: =============================================
::                      EXTRO
                 %Extro% & goto :EOF
::             Any subroutines below here:
:: =============================================




:Adapt_To_Version
:: =============================================

:Check_Home
if not "%Vers_Family%" == "Home" goto Not_Home
%RegRead% "HKEY_LOCAL_MACHINE\SOFTWARE\Acronis\TrueImage\Settings" "MainExePath"
if "%result%" == "NotFound" goto H_3567
call :Check_MainEXE_Version
call :Process_Adapt_To_Version
goto :EOF

:H_3567
%RegRead% "HKEY_LOCAL_MACHINE\SOFTWARE\Acronis\TrueImageHome\Settings" "MainExePath"
if "%result%" == "NotFound" goto Not_Home
call :Check_MainEXE_Version
call :Process_Adapt_To_Version
goto :EOF
:Not_Home

:Check_CorporateWorkstation
if not "%Vers_Family%" == "CorporateWorkstation" goto Not_CorporateWorkstation
%RegRead% "HKEY_LOCAL_MACHINE\SOFTWARE\Acronis\TrueImageWorkstation\Settings" "MainExePath"
if "%result%" == "NotFound" goto Not_Home
call :Check_MainEXE_Version
call :Process_Adapt_To_Version
goto :EOF
:Not_CorporateWorkstation

:Check_Server
if not "%Vers_Family%" == "Server" goto Not_Server
%RegRead% "HKEY_LOCAL_MACHINE\SOFTWARE\Acronis\TrueImageServer\Settings" "MainExePath"
if "%result%" == "NotFound" goto Not_Home
call :Check_MainEXE_Version
call :Process_Adapt_To_Version
goto :EOF
:Not_Server

:Check_Enterprise_Server
if not "%Vers_Family%" == "Enterprise_Server" goto Not_Enterprise_Server
%RegRead% "HKEY_LOCAL_MACHINE\SOFTWARE\Acronis\TrueImageEnterpriseServer\Settings" "MainExePath"
if "%result%" == "NotFound" goto Not_Home
call :Check_MainEXE_Version
call :Process_Adapt_To_Version
goto :EOF
:Not_Enterprise_Server

goto :EOF
:: ========================

:Process_Adapt_To_Version
:: ========================
set U_Restore=0

if "%Vers_Family%" == "Home" (
	if "%TI_Sub_Vers%" LEQ "2337" (
		set ProgPath_REG_KEY=Acronis\TrueImage\Settings
		set LIC_REG_VALUE=standard
		set Lead_Version=H_2337
	)
	if "%TI_Sub_Vers%" == "3567" (
		set ProgPath_REG_KEY=Acronis\TrueImageHome\Settings
		set LIC_REG_VALUE=standard
		set Lead_Version=H_3567
	)
	if "%TI_Sub_Vers%" GEQ "3625" (
		set ProgPath_REG_KEY=Acronis\TrueImageHome\Settings
		set LIC_REG_VALUE=standard
		set Lead_Version=H_3625
	)
)

if "%Vers_Family%" == "CorporateWorkstation" (
	if "%TI_Sub_Vers%" LSS "3625" (
		set ProgPath_REG_KEY=Acronis\TrueImageWorkstation\Settings
		set LIC_REG_VALUE=workstation
		set Lead_Version=CW_3624
	)

	if "%TI_Sub_Vers%" GEQ "3625" (
		set ProgPath_REG_KEY=Acronis\TrueImageWorkstation\Settings
		set LIC_REG_VALUE=workstation
		set Lead_Version=CW_3625
	)
)

if "%Vers_Family%" == "Server" (
	if "%TI_Sub_Vers%" LSS "3625" (
		set ProgPath_REG_KEY=Acronis\TrueImageServer\Settings
		set LIC_REG_VALUE=server
		set Lead_Version=S_3624
	)

	if "%TI_Sub_Vers%" GEQ "3625" (
		set ProgPath_REG_KEY=Acronis\TrueImageServer\Settings
		set LIC_REG_VALUE=server
		set Lead_Version=S_3625
	)
)

if "%Vers_Family%" == "Enterprise_Server" (
	if "%TI_Sub_Vers%" LSS "3625" (
		set ProgPath_REG_KEY=Acronis\TrueImageEnterpriseServer\Settings
		set LIC_REG_VALUE=enterprise
		set Lead_Version=ES_3624
	)

	if "%TI_Sub_Vers%" GEQ "3625" (
		set ProgPath_REG_KEY=Acronis\TrueImageEnterpriseServer\Settings
		set LIC_REG_VALUE=enterprise
		set Lead_Version=ES_3625
	)
)

if "%Vers_Family%" == "Home" goto :EOF
%RegRead% "HKEY_LOCAL_MACHINE\SOFTWARE\Acronis\UniversalRestore" "%LIC_REG_VALUE%" "UniversalRestore_Check"
if not "%UniversalRestore_Check%" == "NotFound" set U_Restore=1

goto :EOF
:: =============================================








:Check_MainEXE_Version
:: ========================
%FileVersion% "%result%"
set TI_vers=%result%
	%String% "%TI_vers%" "token=1,."
	set TI_Main_vers=%result%
if not "%TI_Main_vers%" == "9" goto :EOF

%String% "%TI_vers%" "token=4,."
set TI_Sub_Vers=%result%
goto :EOF
:: ========================



:Veryfy_ProgPath
:: ========================
%SplitPath% "%ProgPath%"
if "%LastDir%" == "Files" set ProgPath=%PathFull3%
if "%LastDir%" == "files" set ProgPath=%PathFull3%
goto :EOF
:: ========================



:Get_SYS_Files
:: ========================
if not exist "SYS\" md "SYS\"
copy "%SystemRoot%\System32\snapapi.dll" "SYS\"
copy "%SystemRoot%\System32\Drivers\snapman.sys" "SYS\"
copy "%SystemRoot%\System32\Drivers\tifsfilt.sys" "SYS\"
copy "%SystemRoot%\System32\Drivers\timntr.sys" "SYS\"

if exist "%SystemRoot%\System32\MSVCP71.DLL" copy "%SystemRoot%\System32\MSVCP71.DLL" "SYS\"
if exist "%SystemRoot%\System32\MSVCR71.DLL" copy "%SystemRoot%\System32\MSVCR71.DLL" "SYS\"
goto :EOF
:: ========================



:ProfileFix_Check
:: ========================
if exist "%PEroot%\UBCD4WinBuilder.exe" (
	set XPE=0
	goto :EOF
)
if exist "%PEroot%\ReatogoBuilder.exe" (
	set XPE=1
	goto :EOF
)

:: find XPE Module in general
if not exist "%OEM1%" goto No_OEM1
pushd "%OEM1%"
for /f "tokens=*" %%a  in ('dir /n /b /s XPELogon.exe') do set XPEpath=%%~dpa
popd
:No_OEM1
if defined XPEpath goto :XPE_Found
pushd "%Plugin%"
for /f "tokens=*" %%a  in ('dir /n /b /s XPELogon.exe') do set XPEpath=%%~dpa
popd
if defined XPEpath goto :XPE_Found
goto :NothingFound
:XPE_Found
if not exist "%XPEpath%xpe.inf" goto :NothingFound
%IniGet% "%XPEpath%xpe.inf" "PEBuilder" "Enable"
if "%result%" == "1" (
	set XPE=1
	goto :EOF
)

:NothingFound
Type "SCRIPTS\DATs\MkDirProfiles.dat" > MkDirProfiles.inf
%TextBox% "1" "Profile Fix Required ..." "ProfileFix_msg.dat"
set XPE=0
goto :EOF
:: ========================




:UPPER_FILTERS
:: ========================
if not exist "%Plugin%\z_UpperFilters\AutoHelp.cmd" (
	%MessageBox% "INFORMATION" "z_UpperFilters plugin missing" "IMPORTANT: ~~You need to download and configure the PlugLab plugin ~~  z_UpperFilters ~~before you can build with this TrueImage plugin. ~~NOTE: it must be the PlugLab plugin for z_UpperFilters as it has extended functions. ~The old plugin that only contains the one file UpperFilters.inf will not work."
	goto :EOF
)
%ConsolidateUpperFilters%
goto :EOF
:: ========================



:DCOM_LAUNCH_FIX
:: ========================
if not exist "%Plugin%\dcomlaunch\dcomlaunch.inf" goto :EOF
%IniSet% "%Plugin%\dcomlaunch\dcomlaunch.inf" "PEBuilder" "Enable" "1"
goto :EOF
:: ========================