@echo off&set FileName=%~n0&shift

:: =============================================
:: AutoHelp PlugLab Concept: 2006 by Reatogo
:: =============================================

:: Help Info:
:: =======================
   set Routine_Type=4
::                  1=Getting Data  2=Prompts  3=Getting Files  4=Creating Files  5=General

   set Routine_Vers=1
   set Routine_Date=2007-02-15
   set RoutineName=CreateNu2XML
   set RoutineAuthor=Siegfried
   set Using_work_from=

   set Example_call_1=%%CreateNu2XML%%
   set Example_call_2=
   set Example_call_3=

   set text_01=Prints a simple Nu2Menu XML to start the main item.
   set text_02=Uses the variables in the head of the autoHelp.cmd.
   set text_03=.
   set text_04=NOTE: the "*_nu2menu.xml" will not be refreshed once created, to avoid that a custom *_nu2menu.xml gets overwritten. If during plugin creation you want the file refreshed with any changed settings in the variables section of the autoHelp.cmd, just delete the file before you configure the plugin.

if "%~1" == "GetHelp" goto :EOF
echo.&echo %*
:: =============================================

set FILE=%Prog_On_CD%_nu2menu.xml

:: set startCMD=Start_%Prog_On_CD%.cmd

if "%SubDir_Of_MainEXE%" == "" goto NoSub
if not "%SubDir_Of_MainEXE:~-1%" == "\" set SubDir_Of_MainEXE=%SubDir_Of_MainEXE%\
:NoSub

	ECHO. %OUT%
	ECHO [Append]%OUT%
	ECHO nu2menu.xml, %FILE% %OUT%
	ECHO. %OUT%

if exist *_nu2menu.xml set FILE=&goto :EOF

set ProgStart4Nu2MenuXML=%ProgStartDRV%:\PROGRAMS
if not "%ProgStartDRV%" == "Y" if not "%ProgStartDRV%" == "B" set ProgStart4Nu2MenuXML=@GetProgramDrive()\Programs


:: XML creation
ECHO ^<!-- Nu2Menu entry for %Prog_On_CD% --^>> %FILE%
ECHO ^<NU2MENU^>>> %FILE%
ECHO 	^<MENU ID="Programs"^>>> %FILE%

if not "%StartMenu_Group%" == "" (
ECHO		^<MITEM TYPE="POPUP" MENUID="%StartMenu_Group%"^>%StartMenu_Group%^</MITEM^>>> %FILE%
ECHO	^</MENU^>>> %FILE%
ECHO	^<MENU ID="%StartMenu_Group%"^>>> %FILE%
)

if not "%StartMenu_Sub_Group%" == "" (
ECHO		^<MITEM TYPE="POPUP" MENUID="%StartMenu_Sub_Group%"^>%StartMenu_Sub_Group%^</MITEM^>>> %FILE%
ECHO	^</MENU^>>> %FILE%
ECHO	^<MENU ID="%StartMenu_Sub_Group%"^>>> %FILE%
)

if "%StartFile%" == "%MainEXE%" (
	ECHO            ^<MITEM TYPE="ITEM" DISABLED= "@Not(@FileExists(%ProgStart4Nu2MenuXML%\%Prog_On_CD%\%SubDir_Of_MainEXE%%StartFile%))" CMD="RUN" FUNC="%ProgStart4Nu2MenuXML%\%Prog_On_CD%\%SubDir_Of_MainEXE%%StartFile%"^>%ShortCut_Name%^</MITEM^>>> %FILE%
) else (
	ECHO            ^<MITEM TYPE="ITEM" DISABLED= "@Not(@FileExists(%ProgStart4Nu2MenuXML%\%Prog_On_CD%\%StartFile%))" CMD="RUN" FUNC="%ProgStart4Nu2MenuXML%\%Prog_On_CD%\%StartFile%"^>%ShortCut_Name%^</MITEM^>>> %FILE%
)


ECHO 	^</MENU^>>> %FILE%
ECHO ^</NU2MENU^>>> %FILE%

set FILE=

goto :EOF
:: =============================================