@echo off&set FileName=%~n0&shift

:: =============================================
:: AutoHelp PlugLab Concept: 2006 by Reatogo
:: =============================================

:: Help Info:
:: =======================
   set Routine_Type=3
::                  1=Getting Data  2=Prompts  3=Getting Files  4=Creating Files  5=General

   set Routine_Vers=1
   set Routine_Date=2007-02-15
   set RoutineName=DWLD
   set RoutineAuthor=Siegfried
   set Using_work_from=

   set Example_call_1=%%DWLD%% "http://www.magicaljellybean.com/files/keyfinder.2.0.beta.2.5.zip"
   set Example_call_2=%%DWLD%% "http://www.magicaljellybean.com/files/keyfinder.2.0.beta.2.5.zip" "keyfinder.2.0.beta.2.5.zip"
   set Example_call_3=

   set text_01=Downlaods a file into the plugin.
   set text_02=If the download file can not be derived from the URL, it must be specified as param 2.
   set text_03=.
   set text_04=Use "set SUPRESS_DWLD_ERR=yes" to bypass error handling

if "%~1" == "GetHelp" goto :EOF
echo.&echo %*
:: =============================================

set DWLD_FILE=%~2
if "%~2" == "" set DWLD_FILE=%~nx1

%FINDAPP% "Download.exe"
set USE_APP="%SharedAPPs%\Download.exe"


if "%DWLD_PROMPT_DONE%" == "yes" goto DWLD_PROMPT_DONE
set WAtext=~Download of %DWLD_FILE% ...
set WAtext2=~
set WAtext3=~
set WAtext4=~~~~Make sure you are online before you continue.
set WAtext5=~
%TEXTBOX% "1" "Download of %DWLD_FILE%" ""

%InetCheck%
if "%result%" == "no" %AbortConfig% "No internet connection."

:DWLD_PROMPT_DONE

set DWLD_PROMPT_DONE=yes

if "%USE_APP%" == "" set DWLD_FILE=%~nx1

%USE_APP% "%~1"

set DwldErr=%errorlevel%

if exist "%~nx1" goto _end
if "%SUPRESS_DWLD_ERR%" == "yes" goto _end


:: Error handling:
set DwldErrMsg=* Download problem. The link is probably no longer valid. *
if "%DwldErr%" == "2" set DwldErrMsg=* Download problem: syntax error *
if "%DwldErr%" == "3" set DwldErrMsg=* Download problem: invalid URL *
if "%DwldErr%" == "4" set DwldErrMsg=* Download problem: unsupported Internet scheme *
if "%DwldErr%" == "5" set DwldErrMsg=* Download problem: session initialization failedL *
if "%DwldErr%" == "6" set DwldErrMsg=* Download problem: connection to server failed *
if "%DwldErr%" == "7" set DwldErrMsg=* Download problem: destination file failure *
if "%DwldErr%" == "8" set DwldErrMsg=* Download problem: destination file failure *

%MessageBox% "INFORMATION" "Download problem with %DWLD_FILE%" "%DwldErrMsg%  ~~Please report a broken links in the forum."

:_end
set SUPRESS_DWLD_ERR=&set DwldErr=&set DwldErrMsg=&goto :EOF
:: =============================================