@echo off&set FileName=%~n0&shift

:: =============================================
:: AutoHelp PlugLab Concept: 2006 by Reatogo
:: =============================================

:: Help Info:
:: =======================
   set Routine_Type=3
::                  1=Getting Data  2=Prompts  3=Getting Files  4=Creating Files  5=General

   set Routine_Vers=1
   set Routine_Date=2007-02-15
   set RoutineName=GetDocs2Ram
   set RoutineAuthor=Siegfried
   set Using_work_from=

   set Example_call_1=%%GetDocs2Ram%% "MyFolder_in_OutDir"
   set Example_call_2=%%GetDocs2Ram%% "sfx"
   set Example_call_3=%%GetDocs2Ram%% "force_sfx"

   set text_01=Transfers the files that have been collected by the "%%GetDocs%%" calls to the RamDrive on CD. 
   set text_02=.
   set text_03=Parameter 1 determines the method: 
   set text_04=.

   set text_05=If a folder name is specified as param. 1, the files will be transferred to a folder with that name in the root of the PEbuilder out-directory.
   set text_06=From there, your postprocessing module has to take over.
   set text_07=Note for Reatogo users: no foldername must be specified. Just use %%GetDocs2Ram%% without parameter. The files will go to "OutDir\$ramdrv$\$profiles$" and will be transferred to CD by the integrated SFX of postprocessing.

   set text_08=.
   set text_09=Parameter 1 = "sfx" will compress the files into an SFX-EXE and a start-CMD will expand it to the RamDrive before the program is started. This method does not require postprocessing. 
   set text_10=Note for Reatogo users: "sfx" must not be specified. Just use %%GetDocs2Ram%% without parameter. The files will go to "OutDir\$ramdrv$\$profiles$" and will be transferred to CD by the integrated SFX of postprocessing.

   set text_11=.
   set text_12=Parameter 1 = "force_sfx" is the universal setting.
   set text_13=It will for non-Reatogo AND for Reatogo users create a SFX to be expanded to the RamDrive by a start-CMD just before the program is started.
   set text_14=.
   set text_15=In essence: use %%GetDocs2Ram%% "force_sfx"
   set text_16=unless it is absolutely essential to have the profile files already on the RamDrive once booted.


if "%~1" == "GetHelp" goto :EOF
:: =============================================

echo %*

if not exist "PROFILES" goto :EOF

if "%~1" == "force_sfx" goto doSFX

:: Reatogo setup: 
if exist "%PEroot%\reatogoBuilder.exe" (
	set OutDirProfileFolder=$ramdrv$\$profiles$
	call :PRINT_DOCS_2_INF
	goto :EOF
)

:: Non-Reatogo setup:
if not "%~1" == "sfx" (
	if not exist "%PEroot%\reatogoBuilder.exe" (
		set OutDirProfileFolder=%~1
		if "%~1" == "" set OutDirProfileFolder=PROFILES
		call :PRINT_DOCS_2_INF
		goto :EOF
	)
)

:doSFX
call :sfxPROFILES

goto :EOF
:: =============================================




:sfxPROFILES
:: ======================
	%FINDAPP% "7za.exe"
	%FINDAPP% "7zCon.sfx"
%SharedAPPs%\7za.exe a -t7z "%CD%\Files\ProfilesSFX.exe" -r "%CD%\PROFILES\*" -aoa -mmt -mx9 2 -sfx
	if exist "%CD%\Files\ProfilesSFX.exe" rd "%CD%\PROFILES" /s /q
goto :EOF
:: ======================



:PRINT_DOCS_2_INF
:: ======================
ECHO.%OUT%
ECHO.%OUT%
ECHO ; Transfer of user profile data from the "%%GetDocs%%" calls : %OUT%
ECHO [WinntDirectories]%OUT%
ECHO z="%OutDirProfileFolder%",2  %OUT%
ECHO [SourceDisksFolders]%OUT%
ECHO PROFILES=z %OUT%
ECHO.%OUT%
ECHO.%OUT%
goto :EOF
:: ======================