@echo off&set FileName=%~n0&shift

:: =============================================
:: AutoHelp PlugLab Concept: 2006 by Reatogo
:: =============================================

:: Help Info:
:: =======================
   set Routine_Type=1
::                  1=Getting Data  2=Prompts  3=Getting Files  4=Creating Files  5=General
:: 1r 2r 3r = always refresh (includes localised text)

   set Routine_Vers=1
   set Routine_Date=2007-04-20
   set RoutineName=VarsSystemEtc
   set RoutineAuthor=Siegfried
   set Using_work_from=

   set Example_call_1=%%VarsSystemEtc%%
   set Example_call_2=
   set Example_call_3=

   set text_01=Defines the variables listed below:
   set text_02=.
   set text_03=%%PEroot%%		is "%PEroot%"
   set text_04=%%Blank_in_Path%%	is "%BLANK_IN_PATH%"
   set text_05=%%Plugin%%		is "%PLUGIN%"
   set text_06=%%OEM1%%		is "%OEM1%"
   set text_07=%%OEM2%%		is "%OEM2%"
   set text_08=%%FullOutDir%%	is "%FullOutDir%"
   set text_09=%%IsoFile%%		is "%isofile%"
   set text_10=.
   set text_11=%%PlugLab_Date%%		is "%PlugLab_Date%"
   set text_12=%%PlugLab_Time%%		is "%PlugLab_Time%"
   set text_13=%%PlugLab_TimeStamp%%	is "%PlugLab_TimeStamp%"
   set text_14=.
   set text_15=%%FileSystem%%	is "%FileSystem%"
   set text_16=%%RegEXEver_Sys%%	is "%RegEXEver_Sys%"
   set text_17=%%OSLang%%		is "%OSLang%"
   set text_18=%%OSVersion%%	is "%OSVersion%"
   set text_19=%%OSBuild%%		is "%OSBuild%"
   set text_20=%%OSServicePack%%	is "%OSServicePack%"
   set text_21=.
   set text_22=%%Source_OSVersion%%	is "%SOURCE_OSVersion%"
   set text_23=%%Source_OSServicePack%%	is "%SOURCE_OSServicePack%"
   set text_24=%%Source_Product_Name%%	is "%SOURCE_PRODUCT_NAME%"
   set text_25=%%Source_CD_Name%%	is "%Source_CD_Name%"
   set text_26=%%Source_Path%%	is "%Source_Path%"
   set text_27=.
   set text_28=%%OemCP%%	is "%OEMCP%"
   set text_29=%%ACP%%	is "%ACP%"
   set text_30=.
   set text_31=%%WorkGroup%%	is "%WorkGroup%"
   set text_32=.
   set text_33=Used for string replacement in Reg2Inf:
   set text_34=%%Dos_ProgramFiles%%	is "%Dos_ProgramFiles%"
   set text_35=.
   set text_36=IMPORTANT note regarding codepages:
   set text_37=The codepage for this entire run has at this stage already been set to ANSI by SCRIPT_MNGR.cmd during the initialisation.
   set text_38=ANSI cp is necessary for special chars, that are not included in OEM cp, to be handled correctly in folder names etc.
   set text_39=The cp setting does not survive the current instance of cmd.exe and it will default to OEM cp again for the next instance of cmd.exe.
   set text_40=.
   set text_41=Should you require OEM cp for any portion of the code in your script, set it temporarely to OEM and then back to ANSI like this:
   set text_42=chcp %%OEMCP%% ^> NUL
   set text_43=- here your code requiring OEM cp -
   set text_44=chcp %%ACP%% ^> NUL


if "%~1" == "GetHelp" goto :EOF
if not exist start.inf.txt echo.&echo %*
:: =============================================

%FindApp% "xFUNCs.exe"

"%APPs%\xFUNCs.exe" "VARS"
if exist "%temp%\TempLab.cmd" (
	call "%temp%\TempLab.cmd"
	del  "%temp%\TempLab.cmd"
)

if defined workgroup goto WGdone
if not exist "%temp%\PlugLabTemp\Get_WG.cmd" (
	echo.> "%temp%\PlugLabTemp\Get_WG.cmd"
	for /f "tokens=1-3*" %%a  in ('netsh diag show computer /v') do if "%%a" == "Domain" echo set WG=%%c>> "%temp%\PlugLabTemp\Get_WG.cmd"
)
call "%temp%\PlugLabTemp\Get_WG.cmd"
if "%WG:~-1%" == ")" set WG=NONE
set Workgroup=%WG%
:WGdone
echo.> "%temp%\PlugLabTemp\%PlugLab_Date%_DateFlag.txt"

:: used for string replacement in Reg2Inf:
call :Dos_ProgramFiles "%ProgramFiles%\*.*"
if exist "%temp%\TempLab.cmd" (
	call "%temp%\TempLab.cmd"
	del  "%temp%\TempLab.cmd"
)


if not "%Using_1x1Script%" == "yes" goto :EOF
if exist "%SharedAPPs%\PEfuncs.exe" goto :EOF
%AbortConfig% "This plugin depends on the plugin 1x1Support_On_CD. Please download and enable the plugin 1x1Support_On_CD."

goto :EOF

:: ====================

:Dos_ProgramFiles
set Dos_ProgramFiles=%~d1%~sp1
echo set Dos_ProgramFiles=%Dos_ProgramFiles:~0,-1%> "%temp%\TempLab.cmd"
goto :EOF